|
<< Click to Display Table of Contents >> Navigation: All About ABAP Technique > ABAP Source Code > YPRACTICE_204 |
*&---------------------------------------------------------------------*
*& Report YPRACTICE_204 *
*& *
*&---------------------------------------------------------------------*
*& *
*& *
*&---------------------------------------------------------------------*
REPORT ypractice_204
NO STANDARD PAGE HEADING.
*----------------------------------------------------------------------*
* Tables
*----------------------------------------------------------------------*
TABLES : ekko, ekpo.
*----------------------------------------------------------------------*
*GLOBAL VARIABLE DECRALATION
*----------------------------------------------------------------------*
DEFINE macro_data_possition.
if &1 = 'HEADER'.
write : /'|' no-gap,(9) &2 centered,
'|' no-gap,(10) &3 centered,
'|' no-gap,(10) &4 centered,
'|' no-gap,(10) &5 centered,
'|' no-gap,(5) &6 centered,
'|' no-gap,(15) &7 centered,
'|' no-gap,(30) &8 centered,
'|' no-gap,(14) &9 centered,
'|' no-gap.
else.
write : /'|' no-gap,(9) &2 centered,
'|' no-gap,(10) &3 ,
'|' no-gap,(10) &4 ,
'|' no-gap,(10) &5 ,
'|' no-gap,(5) &6 ,
'|' no-gap,(15) &7 ,
'|' no-gap,(30) &8 ,
'|' no-gap,(14) &9 right-justified,
'|' no-gap.
endif.
END-OF-DEFINITION.
TYPES : BEGIN OF ty_header,
* information of PO Header
bsart LIKE ekko-bsart,
ebeln LIKE ekko-ebeln,
bukrs LIKE ekko-bukrs,
lifnr LIKE ekko-lifnr,
* information of PO Detail
ebelp LIKE ekpo-ebelp,
matnr LIKE ekpo-matnr,
txz01 LIKE ekpo-txz01,
menge LIKE ekpo-menge,
END OF ty_header.
DATA : gi_header TYPE STANDARD TABLE OF ty_header WITH HEADER LINE,
gi_ekko TYPE STANDARD TABLE OF ekko WITH HEADER LINE,
gi_ekpo TYPE STANDARD TABLE OF ekpo WITH HEADER LINE.
DATA: gw_pri_params TYPE pri_params,
gv_valid TYPE c.
*----------------------------------------------------------------------*
*Input Screen/Selection
*----------------------------------------------------------------------*
SELECTION-SCREEN BEGIN OF BLOCK groupbox1 WITH FRAME TITLE text_101. "declare group box 1
SELECTION-SCREEN BEGIN OF LINE.
SELECTION-SCREEN COMMENT 1(18) text_102 FOR FIELD so_bsart.
SELECT-OPTIONS so_bsart FOR ekko-bsart.
SELECTION-SCREEN END OF LINE.
SELECTION-SCREEN BEGIN OF LINE.
SELECTION-SCREEN COMMENT 1(18) text_103 FOR FIELD so_ebeln.
SELECT-OPTIONS so_ebeln FOR ekko-ebeln.
SELECTION-SCREEN END OF LINE.
SELECTION-SCREEN BEGIN OF LINE.
SELECTION-SCREEN COMMENT 1(18) text_104 FOR FIELD so_bukrs.
SELECT-OPTIONS so_bukrs FOR ekko-bukrs.
SELECTION-SCREEN END OF LINE.
SELECTION-SCREEN END OF BLOCK groupbox1. "End Group Box 1
SELECTION-SCREEN BEGIN OF BLOCK groupbox2 WITH FRAME TITLE text_201. "Declare Group Box 2
SELECTION-SCREEN BEGIN OF LINE.
SELECTION-SCREEN COMMENT 1(18) text_202 FOR FIELD p_mwidth.
PARAMETERS p_mwidth TYPE n DEFAULT 120 LENGTH 4.
SELECTION-SCREEN END OF LINE.
SELECTION-SCREEN BEGIN OF LINE.
SELECTION-SCREEN COMMENT 1(18) text_203 FOR FIELD p_mline .
PARAMETERS p_mline TYPE n DEFAULT 10 LENGTH 4.
SELECTION-SCREEN END OF LINE.
SELECTION-SCREEN END OF BLOCK groupbox2. "End Group Box 2
SELECTION-SCREEN BEGIN OF BLOCK groupbox3 WITH FRAME TITLE text_301. "Declare Group Box 3 - Print Parameter
SELECTION-SCREEN BEGIN OF LINE.
SELECTION-SCREEN COMMENT 1(18) text_311.
PARAMETERS: p_pdest LIKE pri_params-pdest DEFAULT 'LOCL'.
SELECTION-SCREEN END OF LINE.
SELECTION-SCREEN BEGIN OF LINE.
SELECTION-SCREEN COMMENT 1(18) text_312.
PARAMETERS p_paart LIKE pri_params-paart DEFAULT 'X_65_255'.
SELECTION-SCREEN END OF LINE.
SELECTION-SCREEN BEGIN OF LINE.
SELECTION-SCREEN COMMENT 1(18) text_313.
PARAMETERS p_dialog TYPE c AS CHECKBOX DEFAULT 'X'.
SELECTION-SCREEN COMMENT 23(25) text_314 FOR FIELD p_dialog.
SELECTION-SCREEN END OF LINE.
SELECTION-SCREEN ULINE.
SELECTION-SCREEN BEGIN OF LINE.
SELECTION-SCREEN COMMENT 1(18) text_321.
PARAMETERS p_prv RADIOBUTTON GROUP rad1 VISIBLE LENGTH 20 DEFAULT 'X'.
SELECTION-SCREEN COMMENT 23(8) text_322 FOR FIELD p_prv.
PARAMETERS p_prt RADIOBUTTON GROUP rad1.
SELECTION-SCREEN COMMENT 34(8) text_323 FOR FIELD p_prt.
SELECTION-SCREEN END OF LINE.
SELECTION-SCREEN END OF BLOCK groupbox3. "End Group Box 3
*----------------------------------------------------------------------*
*INITIALIZATION
*----------------------------------------------------------------------*
INITIALIZATION.
text_101 = 'Selection Parameter'.
text_102 = 'Order Type'.
text_103 = 'PO Number'.
text_104 = 'Co Code'.
text_201 = 'Page Setup'.
text_202 = 'Max. Width'.
text_203 = 'Max. Line per Page'.
text_301 = 'Print Setup'.
text_311 = 'Output Device'.
text_312 = 'Printer Layout'.
text_313 = ' '.
text_314 = 'Show Printer Dialog'.
text_321 = 'Print Option'.
text_322 = 'Preview'.
text_323 = 'Print'.
*======================================================================*
*MAIN PROGRAM
*Execute after Input Screen
*======================================================================*
START-OF-SELECTION.
FORMAT RESET.
NEW-PAGE LINE-SIZE p_mwidth.
NEW-PAGE LINE-COUNT p_mline.
PERFORM fm_collect_data.
PERFORM fm_process_data.
IF LINES( gi_header ) > 0.
IF p_prt = 'X'.
PERFORM fm_print_setup.
ENDIF.
PERFORM fm_display_data.
ELSE.
PERFORM fm_showmessage.
ENDIF.
END-OF-SELECTION.
*======================================================================*
*SUB PROGRAM / SUB ROUTINE
*======================================================================*
*&--------------------------------------------------------------------*
*& Form fm_collect_data
*&--------------------------------------------------------------------*
* text
*---------------------------------------------------------------------*
FORM fm_collect_data.
* Select PO Header
SELECT ebeln bsart bukrs lifnr
INTO CORRESPONDING FIELDS OF TABLE gi_ekko
FROM ekko
WHERE bsart IN so_bsart AND
ebeln IN so_ebeln AND
bukrs IN so_bukrs AND
bstyp = 'F'.
* Select PO detail
IF NOT gi_ekko[] IS INITIAL.
SELECT ebeln ebelp matnr txz01 menge
INTO CORRESPONDING FIELDS OF TABLE gi_ekpo
FROM ekpo
FOR ALL ENTRIES IN gi_ekko
WHERE ebeln = gi_ekko-ebeln.
ENDIF.
* Notes :
* Avoid using inner join
ENDFORM. "FM_COLLECT_DATA
*&--------------------------------------------------------------------*
*& Form FM_PROCESS_DATA
*&--------------------------------------------------------------------*
* text
*---------------------------------------------------------------------*
FORM fm_process_data.
* Get requirement information
LOOP AT gi_ekko.
LOOP AT gi_ekpo WHERE ebeln = gi_ekko-ebeln.
CLEAR gi_header.
* Get PO Header
gi_header-bsart = gi_ekko-bsart.
gi_header-ebeln = gi_ekko-ebeln.
gi_header-bukrs = gi_ekko-bukrs.
gi_header-lifnr = gi_ekko-lifnr.
* Get PO Detail
gi_header-ebelp = gi_ekpo-ebelp.
gi_header-matnr = gi_ekpo-matnr.
gi_header-txz01 = gi_ekpo-txz01.
gi_header-menge = gi_ekpo-menge.
APPEND gi_header.
ENDLOOP.
ENDLOOP.
ENDFORM. "FM_PROCESS_DATA
*&--------------------------------------------------------------------*
*& Form fm_display_data
*&--------------------------------------------------------------------*
* text
*---------------------------------------------------------------------*
FORM fm_display_data.
FORMAT RESET.
DATA: lv_total_data TYPE i,
lv_header_line TYPE i,
lv_footer_line TYPE i,
lv_max_content TYPE i,
lv_max_data TYPE i,
lv_page_count TYPE i. " LENGTH 4.
* Calculate Page Count
lv_total_data = LINES( gi_header ).
lv_header_line = 5.
lv_footer_line = 3.
lv_max_content = p_mline - lv_header_line - lv_footer_line.
lv_max_data = p_mline - lv_footer_line.
lv_page_count = ( lv_total_data DIV lv_max_content ) + 1.
lv_max_content = lv_max_content + ( lv_header_line - 2 ).
* Display Data to Screen
LOOP AT gi_header.
macro_data_possition : 'CONTENT'
gi_header-bsart
gi_header-ebeln
gi_header-bukrs
gi_header-lifnr
gi_header-ebelp
gi_header-matnr
gi_header-txz01
gi_header-menge.
IF sy-linno = lv_max_data.
PERFORM fm_footer USING lv_page_count.
NEW-PAGE.
ENDIF.
ENDLOOP.
* Create Last Footer
IF sy-linno < lv_max_content.
PERFORM fm_footer USING lv_page_count.
ENDIF.
ENDFORM. "fm_display_data
*&--------------------------------------------------------------------*
*& Form fm_footer
*&--------------------------------------------------------------------*
* text
*---------------------------------------------------------------------*
* -->FV_PAGE_COUtext
*---------------------------------------------------------------------*
FORM fm_footer USING fv_page_count.
* Create Footer Text ( 3 Lines )
ULINE AT (p_mwidth). " Upper frame border
FORMAT COLOR COL_TOTAL INTENSIFIED. " Footer color
WRITE : /'|' NO-GAP, 'Page : ' NO-GAP, (4) sy-pagno NO-GAP, '/', (4) fv_page_count NO-GAP.
WRITE: AT p_mwidth sy-vline. " Right border
ULINE AT (p_mwidth). " Line below titles
FORMAT COLOR OFF.
ENDFORM. "fm_footer
*&--------------------------------------------------------------------*
*& Form fm_print_setup
*&--------------------------------------------------------------------*
* text
*---------------------------------------------------------------------*
FORM fm_print_setup.
DATA: lv_dialog TYPE c.
IF p_prt = 'X'.
IF p_dialog = 'X'.
lv_dialog = ' '.
ELSE.
lv_dialog = 'X'.
ENDIF.
CALL FUNCTION 'GET_PRINT_PARAMETERS'
EXPORTING
destination = p_pdest
immediately = 'X'
draft = ' '
no_dialog = lv_dialog
release = 'X'
layout = p_paart
IMPORTING
out_parameters = gw_pri_params
valid = gv_valid
EXCEPTIONS
archive_info_not_found = 1
invalid_print_params = 2
invalid_archive_params = 3
OTHERS = 4.
* Dot Matrix Setting
* PRINT-CONTROL CPI 17. "CPI cpiLetters per inch
* PRINT-CONTROL LPI 6. "LPI lpiLines per inch
*__________________________________________________
IF sy-subrc <> 0.
MESSAGE ID sy-msgid TYPE sy-msgty NUMBER sy-msgno
WITH sy-msgv1 sy-msgv2 sy-msgv3 sy-msgv4.
ENDIF.
CHECK gv_valid = 'X'.
NEW-PAGE PRINT ON PARAMETERS gw_pri_params NO DIALOG.
ENDIF.
ENDFORM. "fm_print_setup
*&--------------------------------------------------------------------*
*& Form fm_showmessage
*&--------------------------------------------------------------------*
* text
*---------------------------------------------------------------------*
FORM fm_showmessage.
MESSAGE 'File not found.' TYPE 'I'.
ENDFORM. "fm_showmessage
*======================================================================*
*STANDARD EVENT
*======================================================================*
*----------------------------------------------------------------------*
*Page Header
*----------------------------------------------------------------------*
TOP-OF-PAGE.
* Creating Text Header ( 3 Lines )
ULINE AT (p_mwidth). " Upper frame border
FORMAT COLOR COL_HEADING INTENSIFIED. " Title color
macro_data_possition : 'HEADER' 'Doc. Type' 'PO No.' 'Com. Code' 'Vendor' 'Item No.' 'Mat. No.' 'Description' 'Price' .
ULINE AT (p_mwidth). " Line below titles
FORMAT COLOR OFF.